@echo off
echo —————————————————
echo – %~nx0
echo –
echo – Windows Remote Desktop port modification
echo – hint: remote port defaults to 3389 (hex 0xd3d)
echo –
echo - current port (hex):
reg query "HKLM\SYSTEM\CurrentControlSet\Control\Terminal Server\WinStations\RDP-Tcp" /v "PortNumber"
echo —————————————————
:: check admin
net session >nul 2>&1
if %errorLevel% == 0 (echo [administrator mode]) else (echo error: please right click on the file, run as administrator & pause & goto :EOF)
:: check admin
set /p rdp_port="Enter the port number to modify (default is 3389):"
if "%rdp_port%" EQU "" set rdp_port=3389
echo – Press any key to confirm Set the remote desktop port to: %rdp_port%
pause
reg add "HKLM\SYSTEM\CurrentControlSet\Control\Terminal Server\WinStations\RDP-Tcp" /v "PortNumber" /t REG_DWORD /d %rdp_port% /f
echo - new port (hex):
reg query "HKLM\SYSTEM\CurrentControlSet\Control\Terminal Server\WinStations\RDP-Tcp" /v "PortNumber"
echo -- add new port to firewall exceptions ...
netsh advfirewall firewall add rule name="RDP Port %rdp_port%" profile=any protocol=TCP action=allow dir=in localport=%rdp_port%
echo ———— Press any key to restart the TermService service to make the new settings take effect (the remote desktop will be disconnected)
echo ———— If the remote desktop is disconnected and cannot be connected, try restarting the system to take effect
pause
echo --restart Remote Desktop Services...
net stop TermService /y
net start TermService /y
:DONE
echo ———— Done
pause

save to rdp.bat